W pliku przykładowym mam listę powtarzających się liter. Chciałbym obok stworzyć listę unikalnych wartości.
Powyższą operację można wykonać przy pomocy jednej, krótkiej formuły tablicowej.
W komórkach A2:A9 mam moje dane wejściowe. W komórce C2 umieszczam formułę:
1 |
=INDEKS($A$2:$A$9;PODAJ.POZYCJĘ(0;LICZ.JEŻELI($C$1:C1;$A$2:$A$9);0)) |
Jest to formuła tablicowa, należy ją więc zatwierdzić skrótem ctrl+shift+enter, a nie samym enter. Formułę tą przeciągam w dół na obszar odpowiadający obszarowi wejściowemu, czyli C2:C9.
Tylko trzy komórki są wypełnione, ponieważ w zakresie wejściowym są tylko trzy różne znaki. Jeżeli chcemy aby zamiast komunikatu błędu komórka była pusta, należy dodać funkcję, JEŻELI.BŁĄD.
1 |
=JEŻELI.BŁĄD(INDEKS($A$2:$A$9;PODAJ.POZYCJĘ(0;LICZ.JEŻELI($C$1:C1;$A$2:$A$9);0));"") |
Oczywiście powyższą regułę można zastosować dla dowolnych ciągów znaków, lub liczb.
Comments 18
przyda się 🙂
z sortowaniem byłoby lepsze 😉
Dziękuję za odzew. Listę posortowaną można uzyskać z pomocą poniższej formuły tablicowej. Stosuje się ją tak samo jak powyższą. Na podstawie wyniku można wylistować unikaty.
=INDEKS($A$2:$A$9;PODAJ.POZYCJĘ(MIN.K(LICZ.JEŻELI($A$2:$A$9;"<"&$A$2:$A$9);WIERSZ(1:1));LICZ.JEŻELI($A$2:$A$9;"<"&$A$2:$A$9);0))
to ja dziękuję 🙂
teraz jest super!
Cieszę się, że mogłem pomóc. W poniższym poście pokazałem jak uzyskać ten efekt za pomocą jednej formuły.
http://www.123office.pl/2012/06/posortowana-lista-unikalnych-wartosci.html
Używam Excela 2002. Proszę o podpowiedź co jest źle w podanej niżej formule:
JEŻELI(CZY.BŁĄD(INDEKS($A$2:$A$9;PODAJ.POZYCJĘ(0;LICZ.JEŻELI($C$1:C1;$A$2:$A$9);0)));"";INDEKS($A$2:$A$9;PODAJ.POZYCJĘ(0;LICZ.JEŻELI($C$1:C1;$A$2:$A$9);0)))
Zamiast spodziewanej listy unikatów otrzymuję puste komórki…
Podana formuła jest prawidłowa. Proszę pamiętać, że przy tych adresach wejściowych musi być wpisana w komórce C2. Należy ją zatwierdzić przy pomocy skrótu ctrl+shift+enter (w pasku edycji formuła będzie umieszczona w nawiasach klamrowych). Dopiero po takim zatwierdzeniu formułę należy przeciągnąć niżej.
Czy jest też sposób by lista unikatów wyszukiwała się w poziomie (czyli w wierszu od lewej do prawej) a nie tak jak obecnie w pionie? Tzn.:
"A" melduje się tak jak teraz w C2
ale "B" melduje się w D2
"C" melduje się w E2
Występuje problem jeśli w formule wybierzemy zakres A2:15 (bo np chcemy uwzględnić później dodane wartości)
problem jest taki ze na liście pojawia się 0, czy można jakoś łatwo się go pozbyć?
W sprawie pierwszego pytania, trzeba pamiętać aby zmienić zakres w obu miejscach formuły. Żeby rozwiązać Pana drugi problem, należy zmienić formatowanie na niestandardowe o formie :"Standardowy;Standardowy;" (w tym przykładzie w kolumnie C).
Mam taką sytuacje i nie wiem jak ją rozwiązać excelem. Proszę o pomoc
liczba |litera | ilość unikatowych liczb dla litery(rozwiązanie)
1 A A = 3
2 B B = 2
3 A
3 A
4 B
5 A
To zadanie można stosunkowo łatwo rozwiązać przy pomocy tabeli przestawnej. Jeżeli chce Pan jednak osiągnąć wynik jedną formułą, to robi się bardzo skomplikowane. Polecam zadać pytanie na ExcelForum (link powyżej z prawej strony).
A jak całkowicie skasować duplikaty ?
Mam bazę:
A
B
B
C
a chcę skasować duplikaty całkowicie i mieć wynik:
A
C
czyli 'B' ma być całkowicie skasowane bo jest duplikatem.
Jak to zrobić ?
Pierwszą formułę należy zamienić na:
=INDEKS($A$2:$A$9;PODAJ.POZYCJĘ(0;LICZ.JEŻELI($C$1:C1;$A$2:$A$9)+LICZ.JEŻELI($A$2:$A$9;$A$2:$A$9)-1;0))
lub z obsługą błędów:
=JEŻELI.BŁĄD(INDEKS($A$2:$A$9;PODAJ.POZYCJĘ(0;LICZ.JEŻELI($C$1:C1;$A$2:$A$9)+LICZ.JEŻELI($A$2:$A$9;$A$2:$A$9)-1;0));"")
Oczywiście są to formuły tablicowe
Prośba:
Mam takie kolumny:
A 3
B 2
C 14
D 3
B 3
B 5
A 6
ITD…
Jak wyświetlić wartość komórki z drugiej kolumny która jest najwyższa dla danej wartości z pierwszej kolumny.
Coś takiego:
A 3 –
B 2 –
C 14 14
D 3 3
B 3 –
B 5 5
A 6 6
Witam,
Dziękuję za pytanie. Odpowiedziałem Panu w nowym poście:
http://www.123office.pl/2013/01/wybor-wartosci-maksymalnych.html
Pozdrawiam,
bardzo rozsadny artykul – dodalem do ulubionych
Bardzo mi się ta funkcja podoba, ale mam pytanie: jak można rozwinąć funkcję aby wybierała unikaty, ale z określonym warunkiem?
Pozdrawiam